varying vec2 vUv;
uniform sampler2D uTexture;

uniform vec2 uRepeatXY;                  // The number of times the texture is repeated in the x and y directions
uniform vec2 uScrollSpeed;               // The speed at which the texture scrolls in the x and y directions

uniform float uRippleAmplitude;           // The amplitude of the ripple
uniform bool uMirrorEnabled;              // Whether the texture is mirrored

uniform vec3 uColor;                    // The color of the texture

uniform float uTime;                    // The time since the shader was loaded

uniform vec3 uFogColor;
uniform float uFogNear;
uniform float uFogFar;

//	Classic Perlin 2D Noise 
//	by Stefan Gustavson
//
vec4 permute(vec4 x){return mod(((x*34.0)+1.0)*x, 289.0);}

vec2 fade(vec2 t) {return t*t*t*(t*(t*6.0-15.0)+10.0);}

float cnoise(vec2 P){
    vec4 Pi = floor(P.xyxy) + vec4(0.0, 0.0, 1.0, 1.0);
    vec4 Pf = fract(P.xyxy) - vec4(0.0, 0.0, 1.0, 1.0);
    Pi = mod(Pi, 289.0); // To avoid truncation effects in permutation
    vec4 ix = Pi.xzxz;
    vec4 iy = Pi.yyww;
    vec4 fx = Pf.xzxz;
    vec4 fy = Pf.yyww;
    vec4 i = permute(permute(ix) + iy);
    vec4 gx = 2.0 * fract(i * 0.0243902439) - 1.0; // 1/41 = 0.024...
    vec4 gy = abs(gx) - 0.5;
    vec4 tx = floor(gx + 0.5);
    gx = gx - tx;
    vec2 g00 = vec2(gx.x,gy.x);
    vec2 g10 = vec2(gx.y,gy.y);
    vec2 g01 = vec2(gx.z,gy.z);
    vec2 g11 = vec2(gx.w,gy.w);
    vec4 norm = 1.79284291400159 - 0.85373472095314 * 
        vec4(dot(g00, g00), dot(g01, g01), dot(g10, g10), dot(g11, g11));
    g00 *= norm.x;
    g01 *= norm.y;
    g10 *= norm.z;
    g11 *= norm.w;
    float n00 = dot(g00, vec2(fx.x, fy.x));
    float n10 = dot(g10, vec2(fx.y, fy.y));
    float n01 = dot(g01, vec2(fx.z, fy.z));
    float n11 = dot(g11, vec2(fx.w, fy.w));
    vec2 fade_xy = fade(Pf.xy);
    vec2 n_x = mix(vec2(n00, n01), vec2(n10, n11), fade_xy.x);
    float n_xy = mix(n_x.x, n_x.y, fade_xy.y);
    return 2.3 * n_xy;
}

void main() {
    vec2 uv = vUv;

    vec2 repeatXY = uRepeatXY;
    vec2 scrollSpeed = uScrollSpeed;

    float speed = 0.2;
    float time = uTime * speed;

    // Calculate the texture coordinates to create a tiled scrolling effect
    uv.x = fract(uv.x * repeatXY.x + time * scrollSpeed.x);
    uv.y = fract(uv.y * repeatXY.y + time * scrollSpeed.y);

    if (uMirrorEnabled) {
        // Mirror the subtexture depending on the quadrant to create a kaleidoscope effect
        if (uv.x > 0.5) {
            uv.x = 1.0 - uv.x;
        }
        if (uv.y > 0.5) {
            uv.y = 1.0 - uv.y;
        }
    }

    // Animate noise over time
    float noise = cnoise(vec2(uv.x * 8.0, uv.y * 2.0) + time * .2);
    noise = noise * uRippleAmplitude;
    uv += noise * sin(time) * 1.;

    vec4 color = texture2D(uTexture, uv);
    // Discard transparent pixels
    // Outline mode
    if (color.a < 0.1|| color.a > 0.99) {
        gl_FragColor = vec4(0.0);
        discard;
    }

    // Discard pixels near the edge of the texture
    // Discard pixels near the edge of the texture
    if (uv.x < 0.01 || uv.x > 0.99 || uv.y < 0.01 || uv.y > 0.99) {
        gl_FragColor = vec4(0.0);
        discard;
    }
    
    // color = vec4(1.0, 1.0, 0.0, step(0.5, color.a));
    color = vec4(uColor, color.a);

    // Add fog
    float depth = gl_FragCoord.z / gl_FragCoord.w;
    float fogFactor = smoothstep(uFogNear, uFogFar, depth);
    color.rgb = mix(color.rgb, uFogColor, fogFactor);

    // Set the texture color
    gl_FragColor = color;
}